http://www.rpscgi.com/blog.aspx

All the best,
Resource Planning Solutions

http://rpscgi.com

There are five different functions that you should familiarize yourself with–LEFT(), RIGHT(), FIND() LEN() and MID().  Here is how each of them work:

LEFT() – This has only two possible parameters: LEFT(source, # characters).  The source is the text cell to be parsed, and the # characters are the number of characters you want returned beginning from the left most character.  For example, at cell D10 you have the word MOUSE.  The following statement =LEFT(D10,4) would return MOUS, which is the left most four characters.

RIGHT() – This works exactly the same as the LEFT(), just beginning from the opposite side of the text string.  So RIGHT(D10,2), using the same example as above would return SE (the right-most two characters).

FIND() – Like the previous two functions, this function only requires two parameters: FIND(character(s) to be found, source string).  The first parameter needs to be enclosed with double quotes and represents the string to be found.  The second parameter is the cell address of the text string to be searched.  What FIND returns is the position number within our string of the first occurance of the character(s) being sought.  Though this function only requires two parameters, there is a third parameter that is optional, which we will discribe once we have gone through the basics.  So in from our example above, FIND(“O”,D10) would return the number 2.  The letter “O” in MOUSE, is the second character in our simple character string (or text string). 

LEN() – Using the LEN() function just returns the length of the string at that cell.  If we have “The quick brown fox jumped over the lazy dog” in cell B2, then =LEN(B2) will return 44 which is the number of characters in our text string. 

MID() – The MID function has three required parameters: MID(source,starting position, number of characters).  So this function will extract a number of characters from within a text string.  Using the same example, MID(D10,2,1) would return O, which is the second character in our MOUSE string.  We asked the function to start at the second character, which is “O”, with the “2″ at the second parameter, and asked for one character with the “1″ at the third parameter.  If we had MID(D10,2,2), the function would return OU, MID(D10,2,3) would return OUS and so on and so forth. 

So how do all these pieces play together you may wonder.  Well lets start with our original example, you have received a list from your IT department with all the employee names and it is formated with Last Name, First name and you want to parse the names into separate columns (maybe your are going to use the data in a mail merge application later and want the first name in the saluation or whatever the requirement).  So let’s assume that the Last Name, First Name data is in column D, beginning at row 10 and we want the last name in column E and first name column F.  So just call IT and ask them to run another query (just kidding).  You will use the comma as the delimiter.  Typically when names are provided this way, such as “Dean, Jimmy” there is also a blank space to contend with after the comma.  Here we go:

Step 1: Parse out the last name — Using the MID and FIND functions together, we just need to know where the comma is in our string and then subtract one from the number returned from FIND, and that is the number of characters needed in the last name.  The last name starts at the first character so we only have to provide the number “1″ as the correct start location.  With our example text at D10, we want the last name at E10, which would be:

=MID(D10,1,FIND(“,”,D10)-1)

Breaking that down, assuming our first text string is Dean, Jimmy at D10, we tell the MID function to start extracting at the first character, which is the “D” in Dean.  The FIND function is going to look for the first occurance of a comma in the string and return the numeric position in the string, which would be then number 5 (“D” is one, “e” is two, “a” is three, “n” is four and “,” is five).  You will note that we subtracted 1 from the FIND result with FIND(“,”,D10)-1 which is going to return one less than the string position where the comma is located or the number four.  Excel simplifies our MID function to:

MID(D10,1,4) = Dean

Voila, we now have the last name parsed into column E.  Now in order to get the first name into column F, we need to introduce one more function, which is LEN().  The LEN() requires only one parameter, which is the string address.  Our example string–Dean, Jimmy–is eleven characters long (do not forget the blank space after the comma); therefore LEN(D10) would return 10.  Now we have everything we need to parse out the first name.

At F10, we will add the following function =MID(D10,FIND(“,”,D10)+2,LEN(D10).  I know that looks ugly, but hang with me for a minute.  Again, the FIND(“,”,D10) is going to return 5–the position of the comma–and then we need to add 2 to that position to get to our starting point for the string extraction, which is character string number seven (“D” is one, “e” is two, “a” is three, “n” is four, ”,” is five, ” ” or blank space is six, and “J” is seven, which is where we want to start).  The LEN(10) is going to return the total length of our string, which is okay.  We do not have to have the precise number of characters to the end of our string.  We know that the total lenght will get us to the end of the string.  Excel simplifies our second function to:

MID(D10,7,11) = Jimmy

Now that we have the last name and first name parsed into separate columns, you just need to copy and paste the data down through all the rows and your entire list parsed.

A little more complex example:

Now that we are through the basics, you should be aware that you can nest these funtions together for more complex strings.  For example, when can receive a report from our ERP system that includes the assembled part number, a lot number, and the quantity produced.  In this example, the ERP system uses “*” to delimit the three pieces of information, which would look like 7053312-007*154789513*376 for material number 7053312-007, lot number 154789513, with a finish quantity of 376.  Since we are in FP&A, we are just interested in the part number of quantity completed (the Quality department can worry about the lot number).  Our string starts at D10 again and we want the material numbers starting at E10 and the quantity at F10.  In our example, the material number and lot numbers can vary in length, so we will need a little logic to parse our the quantity correctly.

The material number is just like when we parsed “Dean, Jimmy” since we can start at the first character, just our delimiter is now “*” not “,”.  Just use the mid and find functions together to parse out the material number as follows:

MID(D10,1,FIND(“*”,D10)-1) = 7053312-007

Getting to the quantity is a little more complicated.  The FIND function actually has an optional third parameter that have not yet talked about.  The optional third parameter tells the FIND function where to start looking for our FIND.  If it is omitted, then the FIND function begins looking at the first character in our string.  Since we are looking for the second “*”, which is where the quantity starts, our FIND needs to start just past the first “*” inorder to find the second “*” correctly.  In order to do that, we are going to use the third option and actually nest togther two find function.  The formula we will need at F10 for the quantity will be MID(D10,FIND(“*”,D10,FIND(“*”,D10)+1)+1,LEN(D10)), whew! 

The only part that should be new to you is the nested FIND, which is “FIND(“*”,D10,FIND(“*”,D10)+1)”.  Excel will execute the “FIND(“*”,D10)+1″ part first, which is the third parameter.  Remember our string is “7053312-007*154789513*376″ so the “FIND(“*”,D10)+1″ will return thirteen (“7″ is one, “0″ is two, “5″ is three, “3″ is four, “3″ is five, “1″ is six, “2″ is seven, “-” is eight, “0″ is nine, “0″ is ten, “7″ is eleven and the “*” is twelve, plus one is thirteen.  The thirteenth position in our string is where we want to start the search for the second “*”.  Our formula at F10 has now been simplified to MID(D10,FIND(“*”,D10,13)+1,LEN(D10)).  With the third parameter equal to thirteen, we start searching there for the second “*”, which returns twenty-two (“1″ is thirteen, “5″ is fourteen, etc. to the second “*” which is twenty-two, plus one is twenty-three.  The twenty-third position is where our quantity starts.  Again, by just supplying the total length of the string in LEN(D10) we do not have to be concerned with having the precise length of the substring required.  So the remainder simplies to:

MID(D10,23,25) = 376

Hope you found that helpful. If you have a minute give us some feedback about improving the text parsing explanation.

Resource Planning Solutions

www.rpscgi.com

info@rpscgi.com

Here’s an example of how to set up your own customized list.  The first step is to create the list to be customized on a new spreadsheet (or open an existing one with the desired headings).  Our example company uses the following time periods:

Jan ’10 | Feb ’10 | Mar ’10 | 1st Qtr ’10 | Apr ’10 | …. to |Dec ’10 | 4th Qtr ’10 | Total ’10 |

Our list on a worksheet would appear as follows: 

List to be added to Excel's custom list database

Now that we have our list, we just need to add the list to Excel’s “List” database.  First highlight the entire list.  With the list highlighted, select the “Excel Options” from the ribbon (in Excel 2007), as follows:

Select Excel Options

Select Edit custome lists

Select Import

Grab the lower right-hand corner with your mouse and drag

Contact us today to get your free copy of our Top Ten Excel Power User Tips for Accountants and Financial Analysts.  Our Top Ten list is 60+ pages of useful tips gained from years of experience using Excel in a variety of business environments. Just send an email today to info@rpscgi.com, with “Top Ten Tips” in the subject.  Please be sure to include your name, company and business title.

Background

Though Excel provides built-in functionality to consolidate worksheets, it is a bit overly complex for most situations.  The solution that we frequently utilize does consolidate worksheets, without using Excel’s consolidation function, while also giving users more flexibility to change what is being consolidated.   Typically, we will create a series of financial statements that need to be consolidated into a consolidated enterprise.  [Note: Because we typically are consolidating financial statements, most of this tip will be referring to the consolidation of financial statements.]  The supporting financial statements may represent lines of business or divisions or some other entity type.  By using our approach to consolidate worksheets, we can instantly modify the composition of our consolidation by either adding or removing worksheets from the consolidated total.  

The one limitation to this approach is that each worksheet needs to be identically structured relative to the items that are going to be consolidated.  Generally this requirement is not particularly onerous given the nature of worksheet consolidation.  In addition to the line of business-level worksheets, we will need one worksheet that sums all the lines of business as a consolidated financial statement.

 Application

To illustrate, assume that we have a business consisting of three lines of business (LOB) titled LOB1, LOB2 and LOB3.  Each LOB’s P&L and balance sheet is additive to the consolidated financial statement.  In our example, the leadership team is considering adding a fourth LOB and wants to be able to easily consolidate or exclude the fourth LOB, to better analyze LOB4’s impact on the consolidated financial statements.   This will require five worksheets, one for each of the four LOBs and one for the consolidated business.  We start by creating a template for our financial statement with the years going across the columns.  The template looks as follows:

The above worksheet is the template for our consolidated financials as well as for the four LOBs with year 1 starting in column F, and the total market for each LOB starting at row 9.  Each of the LOBs and consolidation worksheets need to be structured the same, for all cells to be consolidated.   So if the 2011 revenue forecast for LOB1 starts at LOB1!F13, with the 2012 forecast at LOB1!G13, then it will be the same for all the other LOB worksheets, as in the following:

Worksheet                     2011                2012                2013        

Revenue LOB1            LOB1!F13          LOB1!G13          LOB1!H13

Revenue LOB2            LOB2!F13          LOB2!G13          LOB2!H13

Revenue LOB3            LOB3!F13          LOB3!G13          LOB3!H13

Revenue LOB4            LOB4!F13          LOB4!G13          LOB4!H13

Given the above format, you could easily consolidate the 2011 forecast with the following formula on the consolidation worksheet:

2011 Consolidated Revenue = LOB1!F13 + LOB2!F13 + LOB3!F13 + LOB4!F13

The issue that arises is when you want to remove one of the LOBs from the consolidation, which means that every formula referencing LOB4 needs to be edited.  Our approach to flexible consolidation eliminates the need to individually reference each worksheet cell as was done above.  In order to make use of the flexible consolidation approach you will need to add two extra worksheets that establish the range.  We usually name the two worksheets “Start” and “End”.  The names can be whatever you like, but should be descriptive.  Once the “Start” and “End”  worksheets have been created, we insert the individual LOB worksheets between them.  When you have created the five worksheets (Summary, LOB1, LOB2, LOB3 and LOB4), and two bookends (Start & End), the ordering of the worksheets needs to appear as follows:

The “Summary” worksheet is where all the worksheets will be consolidated.  In order to SUM the four LOBs, you simply need a formula that can SUM across all the worksheets from “Start” through to “End”.  With the 2011 revenue projections for each LOB at F13 on each of the four worksheets, the 2011 revenue can be consolidated on the Summary worksheet at Summary!F13 with the following formula:

 What is being consolidated: Year 1 revenue for all LOBs

 At Cell Address:  Summary!F13

 Formula: =SUM(Start:End!F13)

 Our new formula–SUM(Start:End!F13)–is equivalent to =Start!F13 + LOB1!F13 + LOB2!F13 + LOB3!F13 + LOB4!F13 + End!F13.   But the new formula is all we need to summarize all four LOB worksheets onto the Summary worksheet.  Now, if we are asked to display the consolidation without LOB4, we simply drag the LOB4 worksheet beyond the “Start” and “End” bookend range.  Once we move the LOB4 worksheet beyond the “End” worksheet, the worksheet tabs now appear as follows:

With LOB4 outside the SUM formula range, the values at Summary!F13 will only include LOB1, LOB2 and LOB3.  And voila, LOB4 is now excluded from the consolidation, without having to adjust a single formula.   This approach will allow us to create some very sophisticated reporting and analysis spread sheets, while permitting addition and deletion of worksheets within our consolidation, with much less formula editing. 

Our example is rather simplistic.  This approach can be used in larger consolidation.  Assume that we have to restructure a sales force with 400 Territories.  Each Territory tiers into a Region, of which there are 20.  Each Region tiers into a District, of which there are four.  The four Districts tier into the total company.  Though this is rather large, if each territory is a worksheet, our approach would permit the required flexibility needed to restructure the entire sales force.  The worksheets might be organized as follows:

Region1Start

  Terrritory001

   Territory005

   …

   Territory150

Region1End

Region2Start

   Territory250

   Territory305

   …

   Territor395

Region2Emd

Through all 20 regions

District1Start

   Region1Summary (This summarizes Region1Start:Region1End)

   Region2Summary (This summarizes Region2Start:Region2End)

   …

   Region7Summary (This summarizes Region7Start:Region7End)

District1End

District2Start

   Region9Summary (This summarizes Region9Start:Region9End)

   Region10Summary (This summarizes Region10Start:Region2End)

   …

   Region15Summary (This summarizes Region15Start:Region15End)

District2End

Through all four districts

TotalCompanyStart

   District1Summary (This summarizes District1Start:District1End)

   District2Summary (This summarizes District2Start:District2End)

   District3Summary (This summarizes District3Start:District3End)

   District4Summary (This summarizes District4Start:District4End)

TotalCompanyEnd

TotalCompany Summary (This summarize TotalCompanyStart:TotalCompanyEnd)

With this structure, without having to manipulate formulas, we could change the composition of our regions and districts very efficiently with only our mouse.   

The one caveat to this approach is that the bookend worksheets (Start and End) are part of the SUM function, which means those worksheets must be blank; otherwise the SUM function will include any data on those two worksheets.  Hopefully you have found this useful.  Send us a message or check out our website at www.rpscgi.com.

RESOURCE PLANNING SOLUTIONS
Email: info@rpscgi.com
Web: www.rpscgi.com

Check out the video for this blog below:

http://www.youtube.com/watch?v=5hb5fFN2chk

CHOOSE(index_number, value1, value2,…)

On the surface, this function doesn’t appear to be particularly helpful. But it can be very helpful when you want to give report users the ability to change the reporting period for financial analysis. For example, you have a report where you want to be able to compare current month actual with current month plan and prior year actual. So you want to allow users to select the period, e.g. 4 for April, and then the report populates the April Plan and actual for 2009 as well as the actual April 2008 and then calculates the variances. Here’s the basic structure that we’ll build off of:

Worksheet #1: Summary for revenue with 2009 current month plan @ C1, 2009 current month actual @ D1 and 2008 prior year month at E1. Cell B1 will represent the current month cell that will be referenced by the CHOOSE function.

Worksheet #2: Plan (Cells are C1 for January 2009 Plan, D1 for February 2009 Plan, and so on through N1 for December 2009 Plan).

Worksheet #3: Actual (Cells are C1 for January 2009 Actual, D1 for February 2009 Actual, and so on through N1 for December 2009 Actual).

Worksheet #4: 2008Actual (Cells are C1 for January 2008 Actual, D1 for February 2008 Actual, and so on through N1 for December 2008 Actual).

So assuming that the “Plan”, “Actual” and “2008Actual” worksheets have been populated, our report users can access the summary worksheet to analyze revenue results.

The formula to retrieve the correct monthly plan from the Plan worksheet, at cell C1 on the summary worksheet, will be:

=CHOOSE(B1,Plan!C1,Plan!D1,Plan!E1,Plan!F1,Plan!G1,Plan!H1,Plan!I1,Plan!J1,Plan!K1,Plan!L1,Plan!M1,Plan!N1)

So on the summary sheet putting 4 at B1 (the index number reference) will return “Plan!E1″ which is the current month plan for April. You can then do the same thing for the Actual and 2008Actual worksheet references in Summary worksheet cells D1 and E1,respectively. Each time the user changes the B1 index number cell, the corresponding month will be retrieve from the Plan, Actual and 2008 Actual worksheets automatically.

Taking the CHOOSE function a little further, you can combine the CHOOSE function with the SUM function. If you wanted a way to sum the year to date total for the plan, it would be as follows:

=SUM(Plan!C1:CHOOSE(B1,Plan!C1,Plan!D1,Plan!E1,Plan!F1,Plan!G1,Plan!H1,Plan!I1,Plan!J1,Plan!K1,Plan!L1,Plan!M1,Plan!N1))

If the index number for B1 was 9, then the formula would provide the year-to-date plan through September by resolving to the formula below:

=SUM(Plan!C1:Plan!K1)

The nice thing is that if B1 were just “1″ meaning the year-to-date January plan, Excel would resolve the formula to:

=SUM(Plan!C1:Plan!C1)

This would be the correct answer because Excel would just return the month of January.

Then finally, what if you want to specify both the start and end range. To do this, you need both and starting and ending CHOOSE function; consequently, we need a start and end index number. For this example B1 is the start index and B2 is the end index. So if B1 has “4″ and B2 has “6″, then the following formula returns the second quarter revenue forecast.

=SUM(CHOOSE(B1,Plan!C1,Plan!D1,Plan!E1,Plan!F1,Plan!G1,Plan!H1,Plan!I1,…):CHOOSE(B2,Plan!C1,Plan!D1,Plan!E1,Plan!F1,Plan!G1,Plan!H1,Plan!I1,…))

This will resolve to the following, which would return the 2Q revenue plan:

=SUM(Plan!F1:Plan!H1)

Using the same approach, you could customize your column headings to match the totals with the following formula for June:

=CHOOSE(B1,”January”,”February”,”March”,”April”,”May”,”June”,”July”,”August”,”September”,”October”,November”,”December”)

Hope you find that helpful. If you would like an Excel example, please shoot me an email and I can forward a file to you.

Check out an example of CHOOSE usage at the following link:

http://www.rpscgi.com/samples/Revenue%20Analysis.xls

RESOURCE PLANNING SOLUTIONS
Email: info@rpscgi.com
Web: www.rpscgi.com

You can also check out two videos on YouTube.com at the following addresses:

Part 1

http://www.youtube.com/user/morrisoc2000#p/a/u/1/c71YGgXQOLA

Part 2

http://www.youtube.com/user/morrisoc2000#p/a/u/0/PtFz-dKRFls

Providing solutions for sustained value creation for emerging and medium size businesses